plugins {
    id 'java'
    id 'maven-publish'
}

group 'com.jessebrault.ssg'
version '0.7.0-SNAPSHOT'

repositories {
    mavenCentral()

    maven {
        name = 'Gitea'
        url = uri('https://git.jessebrault.com/api/packages/jessebrault/maven')
    }
}

configurations {
    testing {
        canBeConsumed = false
        canBeResolved = false
    }
    testImplementation {
        extendsFrom configurations.testing
    }
}

dependencies {
    implementation libs.slf4j.api

    testing libs.slf4j.api
    testing libs.junit.jupiter.api
    testing libs.mockito.core
    testing libs.mockito.junit.jupiter
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

testing {
    suites {
        test {
            useJUnitJupiter()
        }
    }
}

publishing {
    repositories {
        maven {
            name = 'Gitea'
            url = uri('https://git.jessebrault.com/api/packages/jessebrault/maven')

            credentials(HttpHeaderCredentials) {
                name = "Authorization"
                value = "token ${System.getenv("GITEA_ACCESS_TOKEN")}"
            }

            authentication {
                header(HttpHeaderAuthentication)
            }
        }
    }
}